Example of a scatterplot created with Processing. You'll need to create a 'data' folder inside the sketch folder and save twitter.csv inside it. Data: Top 100 Twitter users according to number of followers (in 2010?). Based on https://docs.google.com/spreadsheet/ccc?key=0AonYZs4MzlZbdFRwUEJxd1pQYTF0N0VqSENoY1Z6dWc#gid=0.

twitter.csv

twitter.pde

// Exporteren naar PDF is geen standaard functionaliteit - je hebt daar een externe library voor nodig.
// Hier laten we Processing weten dat we die PDF library willen gebruiken. 
import processing.pdf.*;

// Basis instellingen.
size(1000, 600);
background(255);

// De CSV moet in de sketch folder staan, in een map met de naam 'data'.
// Data van CSV inladen in de variabele 'rijen'. 
// De variabele 'rijen' is een array, een lijst dus.
// Elke element uit de lijst 'rijen' stemt overeen met 1 rij uit de CSV.
// vb: Lady Gaga (@ladygaga),Musician,8914965,144223,642
String rijen[] = loadStrings("twitter.csv");

// Alles wat nu komt zal ook in de PDF zichtbaar zijn.
// De PDF zal in de map van onze sketch staan, met als naam 'twitter.pdf'.
beginRecord(PDF, "twitter.pdf");

// We geven elk element uit onze lijst dezelfde behandeling.
for(int teller = 0; teller < rijen.length; teller ++){

  // Als we de eerste rij inlezen is onze teller gelijk aan nul.
 // Deze rij willen we overslaan, want die bevat de headings: Username, Description, Followers, Following, No of  tweets, Label
 if(teller == 0){
   continue;
 }
 
 // We nemen de rij met als nummer 'teller', en stoppen die in de variabele 'rij'.
 String rij = rijen[teller];
 // De variabele 'rij' bevat nu een lang stuk tekst, terwijl wij met de individuele kolommen willen werken.
 // We moeten dus de tekst in kolommen verdelen, en dat doen we door die te 'spiltten' op de komma.
 String kolommen[] = split(rij, ',');
 
 // We maken hier aparte variabelen voor de verschillende kolommen.
 // Het datatype van de variabelen kolommen is een array van Strings.
 // Dat is ook voor tekstuele gegevens, maar als de cijfers willen we niet als tekst gaan behandelen, maar als getal.
 // Dus moeten we die omzetten naar integers met int(). 
 String naam = kolommen[0]; // 1e kolom
 int followers = int(kolommen[2]); // 3e kolom
 int following = int(kolommen[3]); // 4e kolom
 int tweets = int(kolommen[4]); // 5é kolom
 String label = kolommen[5]; // 6e kolom
 
 float x = map(followers, 1914071, 8914965, 0, width);
 float y = map(tweets, 0, 60693, height, 0);
 float r = map(following, 0, 701159, 5, 20);
 stroke(0);
 noFill();
 ellipse(x, y, r, r);
 
 if(label.equals("ja")){
   noStroke();
   fill(255, 0, 0);
   text(naam, x, y);
 }
  
}

// We zijn klaar met onze PDF, en dat moeten we laten weten aan Processing. 
endRecord();