Embudo by alsostarring.

embudo-scad

/* 
 * 
 * Embudo: SCAD
 * Ver: 1.0
 * by Also Starring (@twitter)
 * MIT Licensed 2012
 *
 */

//Embudo Paramétrico
//-- variables: tres diámetros, de cono a pipa y espesor
module embudo (d1=15, d2=20, d3=100, esp=2)
{
  //-- dos alturas como resultado de la sección áurea del diámetro mayor d1
  hc=d3*5/8;
  hp=d3*3/8;
  $fn=80;

  //-- Debugging tools
  //color("cyan")
  union()
  {
    //-- cono
    difference()
    {
      cylinder(hc,d3/2,d2/2,center=false);
      translate([0,0,-esp])
      cylinder(hc+2*esp,d3/2-esp,d2/2-2*esp,center=false);
    }

    //-- pipa
    difference()
    {
      translate([0,0,hc])
      cylinder(hp,d2/2,d1/2,center=false);
      translate([0,0,hc-esp])
      cylinder(hp+2*esp,d2/2-esp,d1/2-esp,center=false);
    }

    //-- asa
    difference()
    {
      union()
      {
      translate([d3/2-d2/4,-d2/2,0])
      cube([d2,d2,esp], center=false);
      translate([d3/2+d2*3/4,0,0])
      cylinder(esp,d2/2,d2/2,center=false);
      }
      translate([d3/2+d2*3/4,0,-2*esp])
      cylinder(5*esp,d2/2-2*esp,d2/2-2*esp,center=false);
      translate([0,0,-esp])
      cylinder(hc+2*esp,d3/2-esp,d2/2-2*esp,center=false);
    }

  }
}

//-- ejemplia
embudo();
translate([ 0,100,0])
embudo (d1=10, d2=10, d3=20, esp=1);
translate([ 0,-100,0])
embudo (d1=5, d2=10, d3=50, esp=1);