Flake file to setup python/uv environment by supporting .python-version.

flake.nix

{
  description = ''
    Flake file to setup python/uv environment by supporting .python-version.
  '';

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

  outputs = { self, nixpkgs }:
    let
      # Define the systems we want to support
      systems = [
        "x86_64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      # Helper function to create an attrset for each system
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f system);

      # Helper function to get pkgs for each system
      pkgsFor = system: import nixpkgs {
        inherit system;
        overlays = [ ];
      };
    in
    {
      formatter = forAllSystems (system: (pkgsFor system).nixpkgs-fmt);

      devShell = forAllSystems (system:
        let
          pkgs = pkgsFor system;

          # Read the Python version from .python-version file
          pythonVersion = builtins.head (builtins.split "\n" (builtins.readFile ./.python-version));
          # python packages for nix are pythonXXX (e.g. python313 for 3.13)
          pythonMajorVersion = builtins.substring 0 3 (builtins.replaceStrings [ "." ] [ "" ] pythonVersion);
          python = pkgs."python${pythonMajorVersion}";
        in
        pkgs.mkShell {
          buildInputs = with pkgs; [
            python
            uv
          ];

          shellHook = ''
            export PYTHON_VERSION=${pythonVersion}
            mkdir -p .nix/python-${pythonVersion}
            ln -sf ${python}/bin/python $(pwd)/.nix/python-${pythonVersion}/python
            export UV_PYTHON="$(pwd)/.nix/python-${pythonVersion}/python"
            export PATH="$(pwd)/.nix/python-${pythonVersion}:$PATH"
            export UV_PYTHON_INSTALL_DIR="$(pwd)/.nix/python-${pythonVersion}"
            export PATH="$(pwd)/.venv/bin:$PATH"
          '';
        }
      );
    };
}