event-create-view.coffee

class EventCreateView extends Backbone.View
    id: 'overlay'

    initialize: ->
        @template = _.template($('#template-event-create').html())
        @render()

    events: {
        'submit form': 'submit'
        'click .cancel': 'close'
    }

    submit: (event) ->
        event.preventDefault()

        fields = @$el.find('form').serializeArray()
        formObj = {}
        for field in fields
            # Catch start:time and end:time and convert them to datetimes
            if field.name.indexOf(':time') isnt -1
                # get the parent name used in the formObj
                parentName = field.name.split(':time').shift()
                datetime = timeStrToDateStr(field.value, @model.get(parentName))
                formObj[parentName] = datetime
            else
                formObj[field.name] = field.value

        @model.set(formObj)
        @save()

    save: =>
        @model.save null,
            success: (model, response, options) =>
                @close()
                console.debug 'Saved:', model, response, options
            error: (model, xhr, options) =>
                console.error 'Failed saving', model, xhr, options

    close: =>
        if @model.isNew()
            @model.destroy()

        @remove()

    render: ->
        templateVars = @model.toJSON()
        templateVars.startTime = @model.getStartTime()
        templateVars.endTime = @model.getEndTime()

        form = @template(templateVars)
        @$el.html(form)

        return this


window.EventCreateView = EventCreateView