auggie-module.nix

# modules/auggie.nix

{
  config,
  lib,
  pkgs,
  ...
}:
let
  auggie-pkg = pkgs.stdenv.mkDerivation rec {
    pname = "auggie";
    version = "0.5.3";

    src = pkgs.fetchurl {
      url = "https://registry.npmjs.org/@augmentcode/${pname}/-/${pname}-${version}.tgz";
      hash = "sha256-0erVLVh1uPGyurXPzOg6bAyYAEiyXoHy/1Gkz2JfZlM=";
    };

    sourceRoot = "package";

    nativeBuildInputs = [ pkgs.makeBinaryWrapper ];

    installPhase = ''
      runHook preInstall

      mkdir -p $out/bin $out/share/${pname}
      cp -r . $out/share/${pname}

      makeWrapper ${pkgs.nodejs}/bin/node $out/bin/auggie \
        --add-flags $out/share/${pname}/augment.mjs

      runHook postInstall
    '';

    meta = {
      description = "AI agent that brings the power of Augment's agent and context engine into your terminal";
      homepage = "https://docs.augmentcode.com/cli";
      license = lib.licenses.unfree;
      maintainers = with lib.maintainers; [ ];
      platforms = lib.platforms.all;
      mainProgram = "auggie";
    };
  };
in
{
  options.programs.auggie.enable = lib.mkEnableOption ("the Auggie CLI tool");

  config = lib.mkIf config.programs.auggie.enable {
    environment.systemPackages = [ auggie-pkg ];
  };
}