Handling arbitrary array types with transit

transit_arrays.clj

;; clojure -Sdeps '{:deps {com.cognitect/transit-clj {:mvn/version "RELEASE"}}}' -M /tmp/transit_arrays.clj

(require '[cognitect.transit :as transit])

(def default-write-handler
  (transit/write-handler (fn [x]
                           (when (.isArray (class x))
                             "java.array"))
                         (fn [x]
                           (when (.isArray (class x))
                             (vec x)))))

(defn write-transit [v]
  (let [baos (java.io.ByteArrayOutputStream.)]
    (transit/write (transit/writer baos :json
                                   {:default-handler default-write-handler}) v)
    (.toString baos "utf-8")))

(def read-handlers
  (transit/read-handler-map {"java.array" (transit/read-handler into-array)}))

(defn read-transit [s]
  (let [bais (java.io.ByteArrayInputStream. (.getBytes s "UTF-8"))]
    (transit/read (transit/reader bais :json
                                  {:handlers read-handlers}))))

(def read-array (write-transit (into-array String ["foo"])))
(prn read-array)
;;=> "[\"~#java.array\",[\"foo\"]]"
(def written-array (read-transit read-array))
(prn written-array)
;; => #object["[Ljava.lang.String;" 0x58d63b16 "[Ljava.lang.String;@58d63b16"]