Print out 1-100 without using numbers: https://www.facebook.com/ooteensmemes/posts/2805788003017590?comment_id=2806505792945811&reply_comment_id=2806589822937408&notif_id=1614386281359644&notif_t=feed_comment_reply&ref=notif

SolutionWithArith.hs

data Digit = Zero | One | Two | Three | Four | Five | Six | Seven | Eight | Nine
  deriving (Enum)

zero, one, ten :: Int
zero = fromEnum Zero
one = fromEnum One
ten = succ $ fromEnum Nine

main :: IO ()
main = mapM_ print [one .. ten * ten]

SolutionWithEnum.hs

import Data.List (elemIndex)
import Data.Maybe (fromJust)

data Digit = Zero | One | Two | Three | Four | Five | Six | Seven | Eight | Nine
  deriving (Eq, Enum, Bounded)

instance Show Digit where
  show = show . fromEnum

newtype Number = Number' { digits :: [Digit] }

mkNumber :: [Digit] -> Number
mkNumber = Number' . dropWhile (== Zero)

instance Show Number where
  show = concatMap show . digits

oneToHundred :: [Number]
oneToHundred = tail zeroToNinetyNine ++ [oneHundred]
  where
    zeroToNinetyNine =
      [ mkNumber [tensDigit, onesDigit]
      | tensDigit <- [minBound..maxBound]
      , onesDigit <- [minBound..maxBound]
      ]
    oneHundred = mkNumber [One, Zero, Zero]

main :: IO ()
main = mapM_ print oneToHundred

SolutionWithIncr.hs

data Digit = Zero | One | Two | Three | Four | Five | Six | Seven | Eight | Nine
  deriving (Eq, Enum, Bounded)

instance Show Digit where
  show = show . fromEnum

newtype Number = Number { digits :: [Digit] }
  deriving (Eq)

instance Show Number where
  show = concatMap show . digits

incr :: Number -> Number
incr = Number . incrFinal . reverse . digits
  where
    incrFinal [] = error $ "Called incr on Number with no digits"
    incrFinal (d:ds) =
      let (carry, d') = incrDigit d
      in propagateCarry carry ds ++ [d']

    propagateCarry carry [] = if carry then [One] else []
    propagateCarry carry (d:ds) =
      let (carry', d') = if carry then incrDigit d else (False, d)
      in propagateCarry carry' ds ++ [d']

    incrDigit Nine = (True, Zero)
    incrDigit d = (False, succ d)

main :: IO ()
main = mapM_ print $ range one oneHundred
  where
    one = Number [One]
    oneHundred = Number [One, Zero, Zero]
    range start end = takeWhile (/= incr end) $ iterate incr start

oneToHundred = map mkNumber [[Zero, Zero, One] ... [One, Zero, Zero]]

Untested, but shorter :) Might need to make it a triple instead of list and a function to convert from tuple to list but would still be shorter :)

@mihaimaruseac No, there's no Enum instance for tuples 😢 but if arithmetic operations are ok, I have a better solution

Oh, right. The arithmetic solution is great.