isso PKGBUILD

isso.install

post_install() {
echo "By default the database is located in the the temporary location
/tmp/comments.db and the default interface is http://localhost:8080

To change this, edit /etc/isso.conf"
}

isso.service

[Unit]
Description=Isso Comment Server

[Service]
Environment="ISSO_SETTINGS=/etc/isso.conf"
ExecStart=/usr/bin/isso run

[Install]
WantedBy=multi-user.target

PKGBUILD

# Maintainer: Reventlov <[email protected]>
# Contributor: Brice Waegeneire <brice dot wge at gmail dot com>
pkgname=isso
pkgver=0.9.9
pkgrel=2
pkgdesc="A commenting python server similar to disqus"
arch=('any')
url="http://posativ.org/isso/"
license=('MIT')
depends=('python-werkzeug' 'python-html5lib' 'python-misaka' 'python-itsdangerous' 'python-six' 'sqlite' 'python-setuptools')
makedepends=('git' 'python')
backup=('etc/isso.conf')
source=("https://pypi.python.org/packages/source/i/isso/isso-$pkgver.tar.gz"
	"https://pypi.python.org/packages/source/i/isso/isso-$pkgver.tar.gz.asc"
	"https://raw.githubusercontent.com/posativ/isso/master/LICENSE"
	"isso.service")
sha256sums=('f7c07c3f0fc18160603ed680ec213da07818bc53c5b79af6499b76603fc5e07b'
            'SKIP'
            'd909d060d71c4d9ce92102fa68aa53c963db9b4b6ca315fa0817eafb07651fe2'
            '8c9121c8376bba0a8ae9799044a0f70221e4a9cebc9210a33e6bb276172be179')
install=$pkgname.install
validpgpkeys=("7757B21C0C6E5AE4BC6F6462FD1BA15E0E87FE5C")
noextract=()
package() {
  cd "${srcdir}"
  # License
  install -D -m 644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  msg "Starting build..."
  cd "${srcdir}/${pkgname}-${pkgver}"
  python setup.py install --root="${pkgdir}/" --optimize=1
  
  # ... systemd
  install -D -m 644 "${srcdir}/isso.service" "${pkgdir}/usr/lib/systemd/system/isso.service"
  # ... common config
  install -D -m 644 "${srcdir}/${pkgname}-${pkgver}/share/isso.conf" "${pkgdir}/etc/isso.conf"
  # Man pages
  install -D -m 644 "${srcdir}/${pkgname}-${pkgver}/man/man1/isso.1" "${pkgdir}/usr/share/man/man1/isso.1"
  install -D -m 644 "${srcdir}/${pkgname}-${pkgver}/man/man5/isso.conf.5" "${pkgdir}/usr/share/man/man5/isso.conf.5"
}

# vim:set ts=2 sw=2 et: