PKGBUILD for SonnetSuite Professional

PKGBUILD

pkgname=sonnetsuite
pkgver=17.52.1
pkgrel=1
pkgdesc="A 3D Planar High-Frequency Electromagnetic Software"
arch=("x86_64")
url="http://www.sonnetsoftware.com/products/sonnet-suites/"
license=('custom')
depends=('openmotif' 'qwtpolar')
makedepends=('icoutils')
source=("http://www.sonnetsoftware.com/sonnetdl/Sonnet-17-52/sonnetsuite.17.52.1.linux64.tar" 
        "sonnetsuite.desktop")
sha256sums=('14e4a17d3d7086e02748e9c1f6888a13575bcc2b47f819d3fa2cf8aabd236bfb'
            '4ad303cb7dc2f75419b163ccd730f25812195d318e0e16c9d147d71917ae622a')

build() {
        cd "sonnetsoftware"
        sed -n '/LEGAL/,/^you\./ p' sonnetinstall > LICENSE
        bsdtar -xf install/base/base.trz -O | bsdtar -xf - resource/sonnet.ico
        icotool -x resource/sonnet.ico
}

package() {
        install -Dm644 sonnetsuite.desktop "$pkgdir/usr/share/applications/sonnetsuite.desktop"

        cd "sonnetsoftware"
        install -dm755 "$pkgdir/opt/$pkgname"
        echo "$pkgdir/opt/$pkgname" | ./sonnetinstall -skiplicense

        install -Dm644 sonnet_1_256x256x32.png "$pkgdir/usr/share/icons/sonnetsuite.png"
        install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

PKGBUILD_old

# Maintainer: Your Name <[email protected]>
pkgname=sonnetsuite
pkgver=17.52.1
pkgrel=1
epoch=
pkgdesc="A 3D Planar High-Frequency Electromagnetic Software"
arch=("x86_64")
url="http://www.sonnetsoftware.com/products/sonnet-suites/"
license=('unknown')
groups=('lib32')
depends=('openmotif' 'qwtpolar' 'icoutils')
makedepends=()
checkdepends=()
optdepends=()
provides=()
conflicts=()
replaces=()
backup=()
options=()
install=
changelog=
source=("http://www.sonnetsoftware.com/sonnetdl/Sonnet-17-52/sonnetsuite.17.52.1.linux64.tar" 
	"sonnetsuite.desktop")
        
noextract=()
md5sums=('SKIP' 'SKIP')
validpgpkeys=()


package() {
	cd "$srcdir/sonnetsoftware"
	mkdir -p "$pkgdir/opt/$pkgname"
	echo "$pkgdir/opt/$pkgname" | ./sonnetinstall -skiplicense

        echo "SONNET_DIR=/opt/sonnetsuite/; export SONNET_DIR" >> ~/.bashrc
	echo "PATH=$PATH:$SONNET_DIR/bin; export PATH" >> ~/.bashrc

	#For desktop shortcut file

	icotool -x "$pkgdir/opt/sonnetsuite/resource/sonnet.ico"
	
	mkdir -p "$pkgdir/usr/share/icons/"
	mv sonnet_1_256x256x32.png "$pkgdir/usr/share/icons/sonnetsuite.png"

	rm sonnet_2_48x48x32.png sonnet_3_32x32x32.png sonnet_4_16x16x32.png

	#make DESTDIR="$pkgdir/" install
}

sonnetsuite.desktop

[Desktop Entry]

# The type as listed above
Type=Application

# The version of the desktop entry specification to which this file complies
Version=1.0

# The name of the application
Name=sonnetsuite

# A comment which can/will be used as a tooltip
Comment=A 3D Planar High-Frequency Electromagnetic Software

# The path to the folder in which the executable is run
Path=/opt/sonnetsuite/bin

# The executable of the application, possibly with arguments.
Exec=sonnet

# The name of the icon that will be used to display this entry
Icon=sonnetsuite

# Describes whether this application needs to be run in a terminal or not
Terminal=false

# Describes the categories in which this entry should be shown
Categories=Education;