VBScript mini CURL

curl.vbs

Set colNamedArguments = WScript.Arguments.Named

url = colNamedArguments.Item("url")
data = ""
ContentType = "application/x-www-form-urlencoded"

If colNamedArguments.Exists("method") Then
  method = colNamedArguments.Item("method")
Else
  method = "GET"
End If

If colNamedArguments.Exists("json") Then
    ContentType = "application/json"
End If

If colNamedArguments.Exists("dataFile") Then
  Set objFS = CreateObject("Scripting.FileSystemObject")
  dataFile = colNamedArguments.Item("dataFile")
  Set dataFileHandle = objFS.OpenTextFile(dataFile)
  Do Until dataFileHandle.AtEndOfStream
    data = data & dataFileHandle.ReadLine
  Loop
  dataFileHandle.Close
End If

dim xmlhttp: Set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")

xmlhttp.Open method, url, False

xmlhttp.setRequestHeader "Content-Type", ContentType

xmlhttp.send data

WScript.Echo xmlhttp.responseText

Set xmlhttp = Nothing

example usage:

' GET request
cscript \\samba\share\scripts\curl.vbs /url:http://example.com/

' POST request with URL encoded POST data in a file
cscript \\samba\share\scripts\curl.vbs /url:http://example.com/ /dataFile:urlEncodedData.txt /method:POST

' POST request with JSON POST data in a file
cscript \\samba\share\scripts\curl.vbs /url:http://example.com/ /dataFile:jsonData.txt /method:PATCH /json