openscad module for making an upside-down paraboloid

paraboloid.scad

// make an upside-down paraboloid of given height, base radius, and number of steps
module paraboloid(height, radius, n_z=6, n_r=6) {
    // interpolate z-axis using n_z
    zs = [
      for (i=[0:n_z-1])
        i*height/(n_z-1)
    ];
        
    // compute radii for each interpolated layer
    rs = [
      for (i=[0:n_z-1])
        sqrt(height - zs[i])/sqrt(height) * radius
    ];
        
    // enumerate vertices (clockwise)
    vertices = [each
      for (i=[0:n_z-1]) [each 
        for (j=[0:n_r-1]) [
          let (theta=j*360/n_r) (
            [ rs[i]*cos(theta)
            , rs[i]*sin(theta)
            , zs[i] 
            ]
          )
        ]
      ]
    ];
    
    // seal the bottom
    bottom_face = [0,1,2,3,4,5];
        
    // enumerate side faces
    side_faces = [
      each for (i=[0:n_z-2]) [
        each for (j=[0:n_r-1]) [
          let
            ( cur_start  = i*n_r  
            , next_start = (i+1)*n_r
            )
            ( i == n_z-2 ? // last layer, make triangles
                [ cur_start + (j + 1)%n_r
                , cur_start + j
                , next_start + j
                ]
              : // otherwise make quads
                [ cur_start + (j + 1)%n_r
                , cur_start + j
                , next_start + j
                , next_start + (j + 1)%n_r
                ]        
            )
        ]
      ]
    ];
    faces = concat([bottom_face], side_faces);

    polyhedron(vertices, faces);
}

paraboloid(12, 10, n_r=6, n_z=128);

result of running the code above: