break-coins-with-core-logic.clj

break_coins_core_logic.clj

(ns my-coins-project.core
  (:require [clojure.core.logic :as l]
            [clojure.core.logic.fd :as fd]))

(def ^:private coins
  {:penny 1, :nickel 5, :dime 10, :quarter 25})

(defn- fd-sum 
  "Like fd/+ but for more than 2 lvars."
  [[lv1 lv2 & more] total]
  (if-not (seq more)
    (fd/+ lv1 lv2 total)
    (l/fresh [subtotal]
      (fd/+ lv1 lv2 subtotal)
      (fd-sum (cons subtotal more) total))))

(defn- change [amount]
  ;; [coin quantity value]
  (let [coins+lvars (for [[coin-name coin-value] coins]
                      {:coin-name   coin-name
                       :coin-value  coin-value
                       :quantity    (l/lvar)
                       :total-value (l/lvar)})]
    (l/run* [q]
      ;; result == map of coin-name -> quantity
      (l/== q (into {} (for [{:keys [coin-name quantity]} coins+lvars]
                         [coin-name quantity])))
      ;; coin-value * quantity == total-value
      (l/everyg
       (fn [{:keys [coin-value quantity total-value]}]
         (fd/* coin-value quantity total-value))
       coins+lvars)
      ;; each coin total value is between 0 and the `amount` we're making change for
      (l/everyg
       (fn [{:keys [total-value]}]
         (fd/in total-value (fd/interval 0 amount)))
       coins+lvars)
      ;; sum of values == amount
      (fd-sum (map :total-value coins+lvars) amount))))

See also https://gist.github.com/camsaul/b4c1ed2b4ebe70f613edcef4830246c0