Test script for Continuous IDE bug with recursive generic types

aseq.fs

type AsyncSeq<'a> = Async<AsyncInner<'a>>
and AsyncInner<'a> =    
    | AsyncSeqNil
    | AsyncSeqCons of 'a * AsyncSeq<'a>

let rec fold<'a, 'b> (f:'b -> 'a -> 'b) (s:'b) (xs:AsyncSeq<'a>) : Async<'b> = async {
    let! x = xs
    match x with
    | AsyncSeqNil -> return s
    | AsyncSeqCons(head, rest) -> return! fold f (f s head) rest
}

let rec unfold<'a, 'b> (f:'b -> Async<('a * 'b) option>) (s:'b) : AsyncSeq<'a> = async {
    let! x = f s
    match x with
    | None -> return AsyncSeqNil
    | Some(v, s') -> return (AsyncSeqCons(v, unfold f s'))
}

let zeroToNine : AsyncSeq<int> =
    unfold 
        (fun i -> async {
          if i < 10
          then return (Some(i, i+1))
          else return None
        })
        0

let sum : int =
    fold (fun s x -> s+x) 0 zeroToNine
    |> Async.RunSynchronously

printfn "sum = %i" sum

A trivial implementation... Continuous, at the time of this writing has an issue with the 'a type parameter on AsyncSeq. Replacing it with a monomorphic type seems to work but defeats the purpose of such a structure pretty quickly.