Runner for phantom and mocha

runner-mocha.coffee

system = require('system')

##
# Wait until the test condition is true or a timeout occurs. Useful for waiting
# on a server response or for a ui change (fadeIn, etc.) to occur.
#
# @param testFx javascript condition that evaluates to a boolean,
# it can be passed in as a string (e.g.: "1 == 1" or "$('#bar').is(':visible')" or
# as a callback function.
# @param onReady what to do when testFx condition is fulfilled,
# it can be passed in as a string (e.g.: "1 == 1" or "$('#bar').is(':visible')" or
# as a callback function.
# @param timeOutMillis the max amount of time to wait. If not specified, 3 sec is used.
##
waitFor = (testFx, onReady, timeOutMillis=3000) ->
    start = new Date().getTime()
    condition = false
    f = ->
        if (new Date().getTime() - start < timeOutMillis) and not condition
            # If not time-out yet and condition not yet fulfilled
            condition = (if typeof testFx is 'string' then eval testFx else testFx()) #< defensive code
        else
            if not condition
                # If condition still not fulfilled (timeout but condition is 'false')
                console.log "'waitFor()' timeout"
                phantom.exit 1
            else
                # Condition fulfilled (timeout and/or condition is 'true')
                console.log "'waitFor()' finished in #{new Date().getTime() - start}ms."
                if typeof onReady is 'string' then eval onReady else onReady() #< Do what it's supposed to do once the condition is fulfilled
                clearInterval interval #< Stop this interval
    interval = setInterval f, 250 #< repeat check every 250ms


page = require('webpage').create()

page.onConsoleMessage = (msg) -> console.log(msg)
page.onError = (msg) -> console.log(msg)
page.onLoadFinished = (msg) -> console.log("Finished")

page.open "http://localhost:#{system.args[1] or 3000}/test.html", (status) ->
    # Check for page load success
    if status isnt 'success'
        console.log 'Unable to access network'
    else
        waitFor ->
          page.evaluate ->
              document.getElementById('mocha').className is 'end'
        , ->
          failures = page.evaluate ->
            passes = parseInt document.getElementById('passes').innerHTML, 10
            failures = parseInt document.getElementById('failures').innerHTML, 10
            duration = parseFloat document.getElementById('duration').innerHTML
            if failures
              Array::splice.call(document.querySelectorAll('li.test.fail'), 0).forEach (e, i) ->
                console.log e.innerHTML
            console.log "Total: #{passes + failures}, passes: #{passes}, failures: #{failures} in #{duration}s"
            failures
          console.log "Exit with status code #{failures}"
          window.phantom.exit(failures)