showName.hs

#!/usr/bin/env stack
{- stack
  --resolver lts-15.6
  --install-ghc runghc
-}

-- | Demonstrates the 'showName' function.
--
-- @TemplateHaskellQuotes@ is enabled so we can use the @'name@ syntax.
-- @DuplicateRecordFields@ is enabled to show that we handle name mangling.

{-# LANGUAGE TemplateHaskellQuotes #-}
{-# LANGUAGE DuplicateRecordFields #-}
{-# OPTIONS_GHC -Wall #-}

import qualified Language.Haskell.TH.Syntax as TH

-- | Gets the given identifier name as a 'String'.
--
-- If @DuplicateRecordFields@ is enabled, detects the names in the form of
-- @$sel:name:Type@ and extracts the @name@.
showName :: TH.Name -> String
showName (TH.Name (TH.OccName s) _) =
  case s of
    '$' : _ -> takeWhile (/= ':') (drop 5 s)
    _ -> s

data Foo = Foo
  { bar :: Int
  , baz :: Char
  }

spam :: Int
spam = 1

class Eggs a where
  egg :: a

main :: IO ()
main = do
  putStrLn $ showName 'bar
  putStrLn $ showName 'baz
  putStrLn $ showName 'spam
  putStrLn $ showName 'egg

z.console-session

% ./showName.hs
bar
baz
spam
egg