GetModelFromQueryView.dax

EVALUATE
VAR __tables =
    SELECTCOLUMNS(
        INFO.VIEW.TABLES( ),
        "ObjectId", [ID],
        "ObjectType", "Table",
        "Type", "N/A",
        "Object", [Name],
        "Desc", [Description],
        "Hidden", FALSE( ),
        "Expressions", [Expression],
        "Lineage", [LineageTag]
    )
VAR __columns =
    SELECTCOLUMNS(
        FILTER(
            INFO.VIEW.COLUMNS( ),
            [DataCategory] <> "RowNumber"
        ),
        "ObjectId", [ID],
        "ObjectType", "Column",
        "Type", [DataType],
        "Object", [Name],
        "Desc", [Description],
        "Hidden", [IsHidden],
        "Expressions", [Expression],
        "Lineage", [LineageTag]
    )
VAR __measures =
    SELECTCOLUMNS(
        INFO.VIEW.MEASURES( ),
        "ObjectId", [ID],
        "ObjectType", "Measure",
        "Type", [DataType],
        "Object", [Name],
        "Desc", [Description],
        "Hidden", [IsHidden],
        "Expressions", [Expression],
        "Lineage", [LineageTag]
    )
VAR __relationships =
    SELECTCOLUMNS(
        INFO.VIEW.RELATIONSHIPS( ),
        "ObjectId", [ID],
        "ObjectType", "Relationship",
        "Type", "",
        "Object", [Name],
        "Desc",
            CONCATENATEX(
                {
                    { [Relationship] },
                    { "; Cross-Filtering: " },
                    { [CrossFilteringBehavior] }
                },
                [Value] & ""
            ),
        "Hidden", "",
        "Expressions", "",
        "Lineage", ""
    )
VAR __union =
    UNION( __tables, __columns, __measures, __relationships )
RETURN
    __union