Example Configuration build.gradle.kts

.kts

import com.google.devtools.ksp.gradle.KspTaskJvm

buildscript {
    repositories {
        google()
        mavenCentral()

        // Android Build Server
        maven { url = uri("../nowinandroid-prebuilts/m2repository") }
    }
    dependencies {
        classpath(libs.google.oss.licenses.plugin) {
            exclude(group = "com.google.protobuf")
        }
    }
}

// Lists all plugins used throughout the project without applying them.
plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.android.test) apply false
    alias(libs.plugins.baselineprofile) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.serialization) apply false
    alias(libs.plugins.dependencyGuard) apply false
    alias(libs.plugins.firebase.crashlytics) apply false
    alias(libs.plugins.firebase.perf) apply false
    alias(libs.plugins.gms) apply false
    alias(libs.plugins.hilt) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.roborazzi) apply false
    alias(libs.plugins.secrets) apply false
    alias(libs.plugins.room) apply false
}

allprojects {
    val scan = rootProject.buildScan
    tasks.withType<KspTaskJvm>().configureEach {
        doLast {
            if(pluginOptions.isPresent) {
                pluginOptions.get().forEach {
                    it.getAsTaskInputArgs().forEach {
                        scan.value( "${[email protected]}-${it.key}", "${it.value}" )
                    }
                }
            }
        }
    }
}