Yacc program for generating a simple infix calculator

cal.y

%{
/* Example of a Yacc calculator  */
#define YYSTYPE double
#include <stdio.h>
#include <stdlib.h>
#include <math.h>
%}

%token OPERAND
%left  '+' '-'
%left  '*' '/'
%right '^'
%left  UMINUS

%%  /* Grammar rules */
in      :
        |   line in
        ;

line    :   '\n'
        |   expr '\n'               { printf("%lf\n", $1); }
        ;

expr    :   OPERAND                 { $$ = $1; }
        |   expr '+' expr           { $$ = $1 + $3; }
        |   expr '-' expr           { $$ = $1 - $3; }
        |   expr '*' expr           { $$ = $1 * $3; }
        |   expr '/' expr           { $$ = $1 / $3; }
        |   expr '^' expr           { $$ = pow($1, $3); }
        |   '-' expr %prec UMINUS   { $$ = - $2; }
        |   '(' expr ')'            { $$ = $2; }
        ;
%%

int main(void)
{
    return yyparse();
}

int yylex(void)
{
    int c;
    while((c = getchar()) == ' ');
    if(isdigit(c) || c == '.') {
        ungetc(c, stdin);
        scanf("%lf", &yylval);
        return OPERAND;
    }
    return c;
}

Task Four

Build

./build.sh

Content of the shell script build.sh:

yacc cal.y
gcc y.tab.c -o cal -ll -ly -lm

Generated files:

• y.tab.c
• cal executable

Test

./cal

Result:

1+1
2.000000
2+3
5.000000
3+(4*5)
23.000000
3 + (4.2* 2)
11.400000
3.2 + (1/2)
3.700000
3+(1/2)^2
3.250000