My BootWithNoStartup init script for expanded Commodore Amigas, because many people requested it. I mainly use it to run demoscene stuff.

init

.key NOOXY/S,NOKCON/S
.bra {
.ket }

; $VER: init 40.4 (21.5.15) (c) 2003-2015 Charlie/Singular Crew
; Simple initialization script for use with BootWithNoStartup
; on expanded classic Amiga systems.
;
; This script is not generic, and you will probably have to
; customize it for your and your system's needs.
;
; Arguments:
; NOKCON - don't use KingCON as BootWithNoStartup Shell
; NOOXY  - don't fire up a CPU instruction stream patcher

; IDEFix97 is optional, remove this if you use a decent scsi.device
C:User/IDEFix
C:SetPatch
; Remove this if you use newer OSes where NSDPatch is integrated 
; into SetPatch, or you have a plain TD64 setup
C:NSDPatch

Assign ENV: ENVARC:
Assign T: RAM:

; Instead of polluting C:, I use a subdirectory for small utilities,
; like editors, archivers and other small command line stuff.
; Adapt this line for your system, or remove it.
Path C:User ADD

; Use OxyPatcher, unless NOOXY argument was specified
; Invert the IF condition (remove NOT) if you don't like this, 
; or you don't have OxyPatcher. Well, you shouldn't have OxyPatcher
; at all. But in case you still have it...
; Alternatively, you can use CyberPatcher or MuRedux of MMULib fame.
; You can also remove this entirely, if you don't have at least a
; 040 or 060 CPU.
IF NOT {NOOXY}
	C:User/OxyPatcher
ENDIF

; Use KingCON as our default shell in BootWithNoStartup. Invert
; the IF condition (remove NOT) if you don't like this, or you
; don't have KingCON
; Also, make sure you adapt your KingCON-Mountlist location
IF NOT {NOKCON}
	Assign >NIL: DISMOUNT CON:
	Mount CON: FROM DEVS:KingCON-Mountlist
	NewCLI CON:0/0/640/256/AmigaDOS//ASYNC/AUTO//FASTUPDATE/NOCLOSE
	EndCLI
ENDIF

; That's all, folks!