random nerd snipe messing around

area.clj

(ns area
  (:require
    [clojure.math   :as math]
    [criterium.core :as crit]))

(defmulti area :shape)

(defmethod area :square [{:keys [side]}]
  (* side side))

(defmethod area :rectangle [{:keys [width height]}]
  (* width height))

(defmethod area :triangle [{:keys [base height]}]
  (* 0.5 base height))

(defmethod area :circle [{:keys [radius]}]
  (* math/PI radius radius))


(defn make-random-shape []
  (let [shapes  [:square :rectangle :circle :triangle]
        shape   (rand-nth shapes)
        lengths (case shape
                  :square    {:side   (rand-int 10)}
                  :rectangle {:width  (rand-int 10)
                              :height (rand-int 10)}
                  :triangle  {:base   (rand-int 10)
                              :height (rand-int 10)}
                  :circle    {:radius (rand-int 10)})]
    (merge {:shape shape} lengths)))


(defn total-area [shapes]
  (transduce (map area) + shapes))

(def lots-of-shapes (doall (repeatedly 400000 #(make-random-shape))))

(crit/bench (total-area lots-of-shapes))  ;; 56 ms which is 56,000 microseconds