Recommended way to do HTTP requests in ReScript

code.re

// bindings can be isolated/upstreamed. I'm inlining it just for the example
type request;
type response;
[@bs.new] external makeXMLHttpRequest: unit => request = "XMLHttpRequest";
[@bs.send] external addEventListener: (request, string, unit => unit) => unit = "addEventListener";
[@bs.get] external response: request => response = "response";
[@bs.send] external open_: (request, string, string) => unit = "open";
[@bs.send] external send: request => unit = "send";
[@bs.send] external abort: request => unit = "abort";
// =========

// shape of your response
[@bs.scope "JSON"] [@bs.val]
external parseResponse: response => {. "message": array(string)} = "parse";

let request = makeXMLHttpRequest();
request->addEventListener("load", () => {
  let response = request->response->parseResponse;
  Js.log(response##message)
});
request->addEventListener("error", () => {
  Js.log("Error logging here")
});
request->open_("GET", "https://dog.ceo/api/breeds/image/random/3");
request->send;

code.res

// bindings can be isolated/upstreamed. I'm inlining it just for the example
type request
type response
@bs.new external makeXMLHttpRequest: unit => request = "XMLHttpRequest"
@bs.send external addEventListener: (request, string, unit => unit) => unit = "addEventListener"
@bs.get external response: request => response = "response"
@bs.send external open_: (request, string, string) => unit = "open"
@bs.send external send: request => unit = "send"
@bs.send external abort: request => unit = "abort"
// =========

// shape of your response
@bs.scope("JSON") @bs.val
external parseResponse: response => {"message": array<string>} = "parse"

let request = makeXMLHttpRequest()
request->addEventListener("load", () => {
  let response = request->response->parseResponse
  Js.log(response["message"])
})
request->addEventListener("error", () => {
  Js.log("Error logging here")
})
request->open_("GET", "https://dog.ceo/api/breeds/image/random/3")
request->send