Foreign dependency graph

gistfile1.hs

{-# LANGUAGE GeneralizedNewtypeDeriving, TypeFamilies #-}

import Foreign
import System.IO.Unsafe

type family NodeType n

class Ref n where
  withRef :: n -> (Ptr (NodeType n) -> IO b) -> IO b

type instance NodeType (ForeignPtr a) = a
instance Ref (ForeignPtr a) where
  withRef = withForeignPtr

data Child p a = Child p (ForeignPtr a)

type instance NodeType (Child p a) = a
instance Ref p => Ref (Child p a) where
  withRef (Child p fp) f
    = withRef p $ \_ -> withRef fp f

unsafeWithRef :: Ref n => n -> (Ptr (NodeType n) -> IO b) -> b
unsafeWithRef r f = unsafePerformIO $ withRef r f

data CXIndexImpl
type instance NodeType Index = CXIndexImpl
newtype Index = Index (ForeignPtr CXIndexImpl)
  deriving Ref

type instance NodeType TranslationUnit = CXTranslationUnitImpl
data CXTranslationUnitImpl
newtype TranslationUnit = TranslationUnit (Child Index CXTranslationUnitImpl)
  deriving Ref

type instance NodeType Cursor = CXCursor
data CXCursor
newtype Cursor = Cursor (Child TranslationUnit CXCursor)
  deriving Ref

type instance NodeType SourceLocation = CXSourceLocation
data CXSourceLocation
newtype SourceLocation = SourceLocation (Child TranslationUnit CXSourceLocation)
  deriving Ref