Using Extra CFC Attributes for Documentation

autolink.cfm

<cffunction
  name="autoLink"
  returntype="string"
  access="public"
  output="false"
  hint="Turns all URLs and e-mail addresses into clickable links."
  examples='
    ##autoLink("Download Wheels from http://cfwheels.org/download")##
    -> Download Wheels from <a href="http://cfwheels.org/download">http://cfwheels.org/download</a>

    ##autoLink("Email us at [email protected]")##
    -> Email us at <a href="mailto:[email protected]">[email protected]</a>
  '
  categories="view-helper,text"
  functions="excerpt,highlight,simpleFormat,titleize,truncate"
>
  <cfargument name="text" type="string" required="true" hint="The text to create links in.">
  <cfargument name="link" type="string" required="false" default="all" hint="Whether to link URLs, email addresses or both. Possible values are: `all` (default), `URLs` and `emailAddresses`.">
  <cfscript>
    var loc = {};
    loc.urlRegex = "(?ix)([^(url=)|(href=)'""])(((https?)://([^:]+\:[^@]*@)?)([\d\w\-]+\.)?[\w\d\-\.]+\.(com|net|org|info|biz|tv|co\.uk|de|ro|it)(( / [\w\d\.\-@%\\\/:]* )+)?(\?[\w\d\?%,\.\/\##!@:=\+~_\-&amp;]*(?<![\.]))?)";
    loc.mailRegex = "(([^@\s]+)@((?:[-a-z0-9]+\.)+[a-z]{2,}))";
    loc.returnValue = arguments.text;
    if (arguments.link != "emailAddresses")
      loc.returnValue = loc.returnValue.ReplaceAll(loc.urlRegex, "$1<a href=""$2"">$2</a>");
    if (arguments.link != "URLs")
      loc.returnValue = REReplaceNoCase(loc.returnValue, loc.mailRegex, "<a href=""mailto:\1"">\1</a>", "all");
  </cfscript>
  <cfreturn loc.returnValue>
</cffunction>