An attempt to run gnome mobile on NixOS

gnome-mobile.nix

{
  services.xserver.enable = true;
  services.xserver.videoDrivers = [ ];
  services.xserver.displayManager.gdm.enable = true;
  services.xserver.desktopManager.gnome.enable = true;
  nixpkgs.overlays = [
    (final: prev: {
      gnome = prev.gnome // rec {
        mutter = prev.gnome.mutter.overrideAttrs (super: rec {
          version = "0ab630277d225cd0b5a15eac44e31ee16cec6676"; # mobile-shell
          src = prev.fetchFromGitLab {
            domain = "gitlab.gnome.org";
            owner = "verdre";
            repo = "mutter";
            rev = version;
            sha256 = "sha256-txQ3FJ7NyXUg4zgMN9peE3a09xmIr0uEaoo7p0drhoY=";
          };
          patches = [
            (prev.fetchpatch {
              url = "https://gitlab.gnome.org/GNOME/mutter/-/commit/285a5a4d54ca83b136b787ce5ebf1d774f9499d5.patch";
              sha256 = "/npUE3idMSTVlFptsDpZmGWjZ/d2gqruVlJKq4eF4xU=";
            })
          ];
        });
        gnome-shell = (prev.gnome.gnome-shell.override { inherit mutter; }).overrideAttrs (super: rec {
          version = "9e79bfd8d94e59d868705243383fcf4a0142f9d0"; # mobile-shell
          src = prev.fetchFromGitLab {
            domain = "gitlab.gnome.org";
            owner = "verdre";
            repo = "gnome-shell";
            rev = version;
            fetchSubmodules = true;
            sha256 = "sha256-p0NtB+Xi+vk2WoZRbwZ5iYhCGVlRy1vNlr5yBXMmCJA=";
          };
          postPatch = ''
            patchShebangs src/data-to-c.pl
          '';
        });
      };
    })
  ];
}