#unity3d shader showing how to use the step function to avoid using if/else while splitting colors on a shape.

CheapFlip.shader

Shader "Custom/CheapFlip" 
{
	Properties 
	{
		_ColorA ( "Color A", Color ) = ( 1, 1, 1, 1 )
		_ColorB ( "Color B", Color ) = ( 1, 1, 1, 1 )
		
		_MainTex ("Albedo (RGB)", 2D) = "white" {}
		_Glossiness ("Smoothness", Range(0,1)) = 0.5
		_Metallic ("Metallic", Range(0,1)) = 0.0
	}
	
	SubShader 
	{
		Tags { "RenderType"="Opaque" }
		LOD 200
		
		CGPROGRAM
		// Physically based Standard lighting model, and enable shadows on all light types
		#pragma surface surf Standard fullforwardshadows vertex:vert

		// Use shader model 3.0 target, to get nicer looking lighting
		#pragma target 3.0

		sampler2D _MainTex;

		struct Input 
		{
			float2 uv_MainTex;
			float3 localPosition;
		};

		half _Glossiness;
		half _Metallic;
		
		fixed4 _ColorA;
		fixed4 _ColorB;
		
		void vert ( inout appdata_full v, out Input o )
		{
			UNITY_INITIALIZE_OUTPUT( Input, o );
			o.localPosition = v.vertex.xyz;
		}

		void surf ( Input IN, inout SurfaceOutputStandard o ) 
		{
			// Albedo comes from a texture tinted by color
			fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * lerp( _ColorA, _ColorB, step( IN.localPosition.y, 0.0 ) );
			o.Albedo = c.rgb;
			
			// Metallic and smoothness come from slider variables
			o.Metallic = _Metallic;
			o.Smoothness = _Glossiness;
			o.Alpha = c.a;
		}
		ENDCG
	} 
	FallBack "Diffuse"
}