from-nixpkgs-tree-sitter.nix

{tree-sitter, linkFarm, lib}:
let
  make-tree-sitter-libs = grammarFn: (
    let
      grammars = grammarFn tree-sitter.builtGrammars;
      nameForEmacs = origName: (
        let truncated = (lib.strings.removeSuffix "-grammar" origName);
        in "lib" + truncated + ".so"
      );
      linkParser = drv: (
        let
          name = lib.strings.getName drv;
        in {
          name = nameForEmacs name;
          path = "${drv}/parser";
        }
      );
      libDir = linkFarm "grammars-lib" (map linkParser grammars);
    in linkFarm "grammars" [ { name = "lib"; path = "${libDir}"; } ]
  );
in make-tree-sitter-libs (p:
  [
    p.tree-sitter-c
    p.tree-sitter-dockerfile
    p.tree-sitter-java
    p.tree-sitter-javascript
    p.tree-sitter-json
    p.tree-sitter-ruby
    p.tree-sitter-scala
    p.tree-sitter-tsx
    p.tree-sitter-typescript
    p.tree-sitter-yaml
  ]
)

from-raw-source.nix

{inputs, bash, stdenv, writeShellScriptBin}:
{
  src, # Language source
  lang,
  pname ? "tree-sitter-grammar-${lang}",
}:
let
  fakeGit = writeShellScriptBin "git" ''
    echo "Skipping git command"
  '';

  pkg = stdenv.mkDerivation {
    inherit pname src lang;
    buildPhase = ''
      ln -s . tree-sitter-${lang}
      mkdir dist
      bash ${inputs.emacsSrc}/admin/notes/tree-sitter/build-module/build.sh ${lang}
    '';
    installPhase = ''
      mkdir -p $out
      cp --recursive dist $out/lib
    '';
    version = "unstable";
    nativeBuildInputs = [ bash fakeGit ];
  };
in pkg