Install and uninstall Clash of Clans in BlueStacks

COC install.bat

@echo off
::
:: COC install.bat script to install Clash of Clans.
::

Setlocal EnableDelayedExpansion

set "apk_ver=7.200.19"
set "apk_url=http://downloader-apk.com/apps/2015/10/22/clash-of-clans !apk_ver!_[www.Downloader-Apk.com].apk"
set "apk_dst=com.supercell.clashofclans[!apk_ver!].apk"
set "src=%~dp0"
set "src=%src:~0,-1%"
set retry=yes

:: find BlueStacks
set "programfolder="
if exist "%ProgramFiles%\BlueStacks\HD-RunApp.exe" set "programfolder=%ProgramFiles%"
if exist "%ProgramFiles(x86)%\BlueStacks\HD-RunApp.exe" set "programfolder=%ProgramFiles(x86)%"
if "!programfolder!" equ "" (
	echo BlueStacks not found!
	goto :exit
)

:retry
echo Ensure that BlueStacks is running...
net start BstHdAndroidSvc 2>nul
tasklist|find "HD-Frontend.exe">nul
if !errorlevel! geq 1 "!ProgramFolder!\BlueStacks\HD-RunApp.exe"
"!ProgramFolder!\BlueStacks\HD-Adb.exe" start-server
"!ProgramFolder!\BlueStacks\HD-Adb.exe" connect localhost
echo Waiting for BlueStacks (that can take some time)...
"!ProgramFolder!\BlueStacks\HD-Adb.exe" wait-for-device

call :check_error
if "!check_error_continue!" neq "ok" goto !check_error_continue!

::reg query "HKEY_LOCAL_MACHINE\SOFTWARE\BlueStacks\Guests\Android\SharedFolder" /s /f BstSharedFolder|find "HKEY_LOCAL_MACHINE\SOFTWARE\BlueStacks\Guests\Android\SharedFolder">%temp%\BstSharedFolder.keyname.txt
::set /p keyname=<%temp%\BstSharedFolder.keyname.txt
::for /f "usebackq tokens=3*" %%a in (`reg query "%keyname%" /v "Path"^|find "Path"`) do if "%%b" equ "" (set "BstSharedFolder=%%a") else (set "BstSharedFolder=%%a %%b")
::echo !BstSharedFolder!

::"!ProgramFolder!\BlueStacks\HD-GuestCommandRunner.exe"
::"!ProgramFolder!\BlueStacks\HD-Adb.exe" uninstall com.supercell.clashofclans
::dhcpcd -ABDKL -f /system/etc/dhcpcd/dhcpcd.conf -h android-22aa14933d9061fc eth0
::"!ProgramFolder!\BlueStacks\HD-Adb.exe" shell wget -O "/sdcard/windows/BstSharedFolder/com.supercell.clashofclans[7.200.19].apk" "http://downloader-apk.com/apps/2015/10/22/clash-of-clans%207.200.19_[www.Downloader-Apk.com].apk"

echo.
if not exist "%temp%\!apk_dst!" (
	echo Downloading Clash of Clans...
	powershell -NoProfile -NonInteractive -Command "(New-Object System.Net.WebClient).DownloadFile('!apk_url!','%temp%\!apk_dst!')"
	echo.
)
echo Installing Clash of Clans...
"!ProgramFolder!\BlueStacks\HD-Adb.exe" install "%temp%\!apk_dst!"

:exit
echo.
pause
exit /b

:check_error 
set check_error_continue=ok
if !errorlevel! equ 0 exit /b 0

if !retry! equ yes (
	set retry=no
	echo.
	echo Some problem occurred, stop BlueStacks service...
	net stop BstHdAndroidSvc
	set check_error_continue=retry
) else (
	echo.
	echo Cannot communicate with BlueStacks.
	echo Exit now!
	set check_error_continue=exit
)
exit /b

COC uninstall.bat

@echo off
::
:: COC uninstall.bat script to remove Clash of Clans and its folder.
::

Setlocal EnableDelayedExpansion

set "src=%~dp0"
set "src=%src:~0,-1%"
set retry=yes

:: find BlueStacks
set "programfolder="
if exist "%ProgramFiles%\BlueStacks\HD-RunApp.exe" set "programfolder=%ProgramFiles%"
if exist "%ProgramFiles(x86)%\BlueStacks\HD-RunApp.exe" set "programfolder=%ProgramFiles(x86)%"
if "!programfolder!" equ "" (
	echo BlueStacks not found!
	goto :exit
)

:retry
echo Ensure that BlueStacks is running...
net start BstHdAndroidSvc 2>nul
tasklist|find "HD-Frontend.exe">nul
if !errorlevel! geq 1 "!ProgramFolder!\BlueStacks\HD-RunApp.exe"
"!ProgramFolder!\BlueStacks\HD-Adb.exe" start-server
"!ProgramFolder!\BlueStacks\HD-Adb.exe" connect localhost
echo Waiting for BlueStacks (that can take some time)...
"!ProgramFolder!\BlueStacks\HD-Adb.exe" wait-for-device

call :check_error
if "!check_error_continue!" neq "ok" goto !check_error_continue!

echo.
echo Uninstall Clash of Clans...
"!ProgramFolder!\BlueStacks\HD-Adb.exe" uninstall com.supercell.clashofclans
echo.
echo Delete Clash of Clans folder /data/data/com.supercell.clashofclans...
"!ProgramFolder!\BlueStacks\HD-Adb.exe" shell su -c "rm -r /data/data/com.supercell.clashofclans"

call :check_error
if "!check_error_continue!" neq "ok" goto !check_error_continue!

:exit
echo.
pause
exit /b

:check_error 
set check_error_continue=ok
if !errorlevel! equ 0 exit /b 0

if !retry! equ yes (
	set retry=no
	echo.
	echo Some problem occurred, stop BlueStacks service...
	net stop BstHdAndroidSvc
	set check_error_continue=retry
) else (
	echo.
	echo Cannot communicate with BlueStacks.
	echo Exit now!
	set check_error_continue=exit
)
exit /b