PKGBUILD

# Maintainer: Helle Vaanzinn <[email protected]>

pkgname=xcursor-thedot
pkgver=0.6
pkgrel=2
pkgdesc="A mouse theme with circles"
arch=(x86_64)
url="https://www.gnome-look.org/p/999763/"
license=('GPL')
source=("https://bitbucket.org/sergiy_ilchuk/thedot/get/0362c13478d3.zip"
    "${pkgname}.patch")
sha256sums=('114662e67136340c40f4cd90b2a5455f42cec7263e84224bb7d7acb5f5f3a142'
            'b23775483a7f5bafde624a7fe370c65ebcef6617aa56bf0e1863aba4069f3ed0')

prepare() {
    cd "sergiy_ilchuk-thedot-0362c13478d3"

    ## patches
    # never use spaces in file names
    patch -Np1 -i ../${pkgname}.patch
}

package() {
    cd "sergiy_ilchuk-thedot-0362c13478d3"

    install -dm755 "$pkgdir"/usr/share/icons/
    cp -vR Dot-{Dark,Light} "$pkgdir"/usr/share/icons/
    rm "$pkgdir"/usr/share/icons/Dot-{Dark,Light}/cursor.theme

    # gnome-shell compatibility
    cd "${pkgdir}/usr/share/icons"
    for _dir in "Dot-Dark" "Dot-Light"; do
        cd "${_dir}/cursors"
        ln -s ./question_arrow ./dnd-ask
        ln -s ./plus ./dnd-copy
        ln -s ./link ./dnd-link
        ln -s ./move ./dnd-move
        ln -s ./circle ./dnd-none
        cd ../..
    done

}

xcursor-thedot.patch

--- a/Dot-Dark/index.theme
+++ b/Dot-Dark/index.theme
@@ -1,3 +1,3 @@
 [Icon Theme]
-Name=TheDOT 0.3 dark
-Comment=Good white modern-looking theme with a piece of nostalgia
+Name=Dot-Dark
+Comment=Mouse theme with circles
 
--- a/Dot-Light/index.theme
+++ b/Dot-Light/index.theme
@@ -1,3 +1,3 @@
 [Icon Theme]
-Name=TheDOT 0.3 light
-Comment=Good white modern-looking theme with a piece of nostalgia
+Name=Dot-Light
+Comment=Mouse theme with circles