qtkeychain.bat

@echo off

REM LS: last successful build: 2017/01/19
REM     off of master branch:  10b2a2baeb5e016d73bc3e88d188eba38466b796 

call "%~dp0\o4w-build-env-64.bat"

set BUILDCONF=Release

echo "PATH: %PATH%"

cd /D %WORKSPACE%

rd /s /q build
md build
cd /D build

REM cmake -G "Ninja" ^
cmake -G "Visual Studio 10 Win64" ^
  -D CMAKE_INSTALL_PREFIX=%O4W_ROOT% ^
  -D CMAKE_BUILD_TYPE=%BUILDCONF% ^
  -D CMAKE_CONFIGURATION_TYPES=%BUILDCONF% ^
  -D CMAKE_PREFIX_PATH:STRING=%OSGEO4W_ROOT% ^
  -D BUILD_WITH_QT4:BOOL=ON ^
  -D BUILD_TRANSLATIONS:BOOL=OFF ^
  ..
if errorlevel 1 goto error

cmake --build . --config %BUILDCONF%
if errorlevel 1 goto error

cmake --build . --target INSTALL --config %BUILDCONF%
if errorlevel 1 goto error

:finish
exit /b

:error
echo Failed with error #%errorlevel%.
exit /b %errorlevel%

REM Install log example
REM -- Install configuration: "Release"
REM -- Installing: Z:/OSGeo4W64/include/qtkeychain/keychain.h
REM -- Installing: Z:/OSGeo4W64/include/qtkeychain/qkeychain_export.h

REM -- Installing: Z:/OSGeo4W64/lib/qtkeychain.lib
REM -- Installing: Z:/OSGeo4W64/bin/qtkeychain.dll

REM -- Installing: Z:/OSGeo4W64/mkspecs/modules/qt_QtKeychain.pri
REM -- Installing: Z:/OSGeo4W64/lib/cmake/QtKeychain/QtKeychainLibraryDepends.cmake
REM -- Installing: Z:/OSGeo4W64/lib/cmake/QtKeychain/QtKeychainLibraryDepends-release.cmake
REM -- Installing: Z:/OSGeo4W64/lib/cmake/QtKeychain/QtKeychainConfig.cmake
REM -- Installing: Z:/OSGeo4W64/lib/cmake/QtKeychain/QtKeychainConfigVersion.cmake