Fallout 3 Menu

launch.bat

@ECHO OFF

start "Fallout 3 Menu" cmd /c launch_menu.bat

launch_menu.bat

@ECHO OFF
TITLE Fallout 3 Menu
CLS

:MENU
CLS

ECHO.
ECHO   =========== FALLOUT 3 MENU ===========
ECHO.
ECHO     1.  Start with FOSE (default)
ECHO     2.  Start launcher
ECHO     3.  Start directly
ECHO.
ECHO     4.  Autosort mods with BOSS
ECHO.
ECHO     Q.  Exit
ECHO.
ECHO   ======================================
ECHO.

SET INPUT=
SET /P "INPUT=  Select an option [1]: "

IF /I '%INPUT%'==''  GOTO StartFOSE
IF /I '%INPUT%'=='1' GOTO StartFOSE
IF /I '%INPUT%'=='2' GOTO StartFalloutLauncher
IF /I '%INPUT%'=='3' GOTO StartFallout3
IF /I '%INPUT%'=='4' GOTO RunBOSS
IF /I '%INPUT%'=='Q' GOTO Quit

CLS
GOTO MENU

:StartFOSE
CLS
ECHO.
ECHO   ^>^> Starting FOSE Loader
START "" fose_loader.exe
EXIT

:StartFalloutLauncher
CLS
ECHO.
ECHO   ^>^> Starting Fallout Launcher
START "" FalloutLauncher.exe
GOTO MENU

:StartFallout3
CLS
ECHO.
ECHO   ^>^> Starting Fallout 3
START "" Fallout3.exe
EXIT

:RunBOSS
CLS
ECHO.
ECHO   ^>^> Running BOSS
boss.exe --update --silent --game Fallout3
ECHO Completed!
ECHO.
PAUSE
GOTO MENU

:Quit
EXIT