default.nix

{ stdenv
, fetchFromGitLab
, autoreconfHook
, pkg-config
, intltool
, itstool
, mono
, yelp-tools
, wrapGAppsHook
, enchant1
, glib
, gnome3
, gtk-sharp-3_0
, gst_all_1
, libxml2
}:
let
  version = "1.6";
in
stdenv.mkDerivation {
  pname = "gnome-subtitles";
  inherit version;

  src = fetchFromGitLab {
    domain = "gitlab.gnome.org";
    owner = "GNOME";
    repo = "gnome-subtitles";
    rev = "gnome-subtitles-${version}";
    sha256 = "1crmmcx32i6ca7dlr3xhnc7vgv9jhlpwh6hxhv2fl1x1zbasf42z";
  };

  nativeBuildInputs = [
    wrapGAppsHook
    autoreconfHook
    mono
    intltool
    itstool
    pkg-config
    yelp-tools
  ];

  buildInputs = [
    enchant1
    gnome3.gtk
    libxml2
    glib
    gtk-sharp-3_0
  ] ++ (with gst_all_1; [
    gst-plugins-base
    (gst-plugins-good.override {
      gtkSupport = true;
    })
  ]);

  preConfigure = ''
    intltoolize
  '';

  preFixup =
    let
      libPath = stdenv.lib.makeLibraryPath [
        enchant1
        glib
        gnome3.gtk
      ];
    in
    ''
      gappsWrapperArgs+=(
        --prefix MONO_PATH : "${gtk-sharp-3_0}/lib/mono/gtk-sharp-3.0"
        --prefix LD_LIBRARY_PATH : "${libPath}"
      )
    '';

  meta = with stdenv.lib; {
    description = "Subtitle editor for the GNOME desktop";
    homepage = "http://gnomesubtitles.org/";
    license = licenses.gpl2;
    maintainers = with maintainers; [ dasj19 ];
    platforms = platforms.unix;
  };
}