gistfile1.rkt

(define-syntax (singleton-struct stx)
  (syntax-case stx ()
    ((_ name others ...)
     (let-syntax ((name? (syntax-append #'name #'?)))
       #'(define-values
           (name name?)
           (let ()
             (struct name () others ...)
             (values (name) name?)))))))

(define-for-syntax (syntax-append s1 s2)
  (quasisyntax
   (unsyntax
    (string->symbol
     (string-append (symbol->string (syntax-e s1))
                    (symbol->string (syntax-e s2)))))))

That occurrence of syntax-append is at phase 2: it's +1 for being on the rhs of a define-syntax and another +1 for being on the rhs of let-syntax. But define-for-syntax defines something at +1 of where it's located.

This is probably closer to what you want, but you're still not going to correctly capture the predicate name:

(define-syntax (singleton-struct stx)
  (syntax-case stx ()
    ((_ name others ...)
     (with-syntax ((name? (syntax-append #'name #'?)))
       #'(define-values
           (name name?)
           (let ()
             (struct name () others ...)
             (values (name) name?)))))))

Thanks, I get burned by let-syntax every time.

I ended up using format-id.

(define-syntax (singleton-struct stx)
  (syntax-case stx ()
    ((_ name others ...)
     (with-syntax ((name? (format-id #'name "~a?" (syntax-e #'name))))
       #'(define-values
           (name name?)
           (let ()
             (struct name () others ...)
             (values (name) name?)))))))