perl script to drop into /etc/cron.hourly (or whatever) to clean up core files

corefiles.pl

#!/usr/bin/perl
# drop into /etc/cron.hourly (or whatever) to clean up core files
use warnings;
use strict;

use File::Find;
use File::LibMagic;
use Number::Bytes::Human;

sub wanted;

# global vars!
use vars qw/*name *prune $magic $human/;
*name  = *File::Find::name;
#*dir   = *File::Find::dir;
*prune = *File::Find::prune;
$magic = File::LibMagic->new();
$human = Number::Bytes::Human->new(bs=>1024, suffixes=>'si_1000');

File::Find::find(\&wanted, q{/});
exit;

sub wanted {
    if ( $name eq q{/proc}
      or $name eq q{/var/named/run-root/proc}
      or $name eq q{/dev}
      or $name eq q{/sys}
    ){
        $prune = 1;
        return;
    }

    return unless -f _;
    return unless /^core\.\d+\z/s;
    my $type = $magic->checktype_filename($name);
    if( $type =~ m{application/x-(empty|coredump)} ){
        my ($size,$atime) = (lstat(_))[7,8];
        my $t = localtime($atime);
        my $s = $size ? $human->format($size) : q{empty};
        print(qq{removing $s file '$name' from $t ($type)\n});
        unlink($name) or warn qq{Failed removing $name\n};
    }
}

Ideally, things would be fixed so core files aren't generated all the time to begin with, but for stopgap purposes in a specific, annoying situation... 😢