Scripts to switch dark mode / light mode for my main apps

dark_mode.applescript

-- turn on Dark Mode on macOS
tell application "System Events"
	tell appearance preferences
		set dark mode to true
	end tell
end tell
-- turn on Dark Palette on OmniFocus
tell application "OmniFocus"
	set value of preference id "OFIColorPaletteIdentifier" to "builtin:OmniFocus Dark"
end tell
-- copy settings file to Sublime Text 3
do shell script "cp ~/etc/ST3_pref_dark.json ~/Library/Application\\ Support/Sublime\\ Text\\ 3/Packages/User/Preferences.sublime-settings"
-- iTerm
-- Ideally I would change profile or default profile, but it's not exposed to AppleScript
tell application "iTerm"
	repeat with theWindow in windows
		repeat with theTab in tabs of theWindow
			repeat with theSession in sessions of theTab
				tell theSession
					set color preset to "Solarized Dark"
				end tell
			end repeat
		end repeat
	end repeat
end tell
-- Alfred
tell application "Alfred 3"
	set theme "Alfred macOS Dark"
end tell
-- Bear Notes
open location "bear://x-callback-url/change-theme?theme=Solarized%20Dark"

light_mode.applescript

-- turn on Dark Mode on macOS
tell application "System Events"
	tell appearance preferences
		set dark mode to false
	end tell
end tell
-- turn on Dark Palette on OmniFocus
tell application "OmniFocus"
	set value of preference id "OFIColorPaletteIdentifier" to "default"
end tell
-- copy settings file to Sublime Text 3
do shell script "cp ~/etc/ST3_pref_light.json ~/Library/Application\\ Support/Sublime\\ Text\\ 3/Packages/User/Preferences.sublime-settings"
-- iTerm
-- Ideally I would change profile or default profile, but it's not exposed to AppleScript
tell application "iTerm"
	repeat with theWindow in windows
		repeat with theTab in tabs of theWindow
			repeat with theSession in sessions of theTab
				tell theSession
					set color preset to "Solarized Light"
				end tell
			end repeat
		end repeat
	end repeat
end tell
-- Alfred
tell application "Alfred 3"
	set theme "Alfred macOS"
end tell
-- Bear Notes
open location "bear://x-callback-url/change-theme?theme=Solarized%20Light"