Light Lines (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Light Lines
author David Crespo
homepage www.puzzlescript.net
key_repeat_interval 0.2
( debug )

========
OBJECTS
========

Background
#672577
00000
00000
00000
00000
00000

Wire
gray blue
.010.
00100
11111
00100
.010.

LiveWire
gray lightblue
.010.
00100
11111
00100
.010.

Player
orange blue yellow
00200
.222.
21112
.111.
.1.1.

Light
gray darkgray
00100
01110
11111
01110
00100

LitLight
gray white
00100
01110
11111
01110
00100

=======
LEGEND
=======

. = Background
P = Player
O = Light
* = LitLight
+ = Wire

Hot = LitLight or LiveWire

=======
SOUNDS
=======



================
COLLISIONLAYERS
================

Background
Player, Light, LitLight, Wire, LiveWire

======
RULES
======

( Everything wants to be off )
[ LitLight ] -> [ Light ]
[ LiveWire ] -> [ Wire ]

( wires are pushable, up to 2 at a time )
[ > Player | Wire ] -> [ > Player | > Wire ]
( this covers LiveWire bc it goes back to Wire in the first half of the turn )
[ > Player | Wire | Wire ] -> [ > Player | > Wire | > Wire ]

( Loop needed to get through chains of light-wire-light-wire-light )
startloop
  late [ Player | Light ] -> [ Player | LitLight ]
  late [ Hot | Wire ] -> [ Hot | LiveWire ]
  late [ Hot | Light ] -> [ Hot | LitLight ]
endloop


( Ideas/Questions:

- Idea: Lights that can only be connected from certain sides: LightL, LightUR, etc.
- Trigger lights the player can light by touching, other lights can't be triggered
- Those two ideas combine well: the player can only light a light from a side with an exposed wire. That means only lights with more than one exposed wire are any use to the player for touching directly
- Separate stationary from being light or a wire? Eh, I kind of like it. Wires: you can't light them directly, and you can move them. That's it.
- What if you can only push multiple blocks if they're live or lit?

)

==============
WINCONDITIONS
==============

No Light

=======
LEVELS
=======

message light all the lights!

( touch a light )
......
.p....
......
......
..o...
......


( chain of lights )
......
....o.
.p..o.
....o.
......
......

( light two at once )
......
....o.
.p....
....o.
......
......

( a wire, too boring though )
( ...... )
( ....o. )
( .p.... )
( ....o. )
( ...+.. )
( ....o. )

( a wire -- more interesting )
........
....ooo.
.p..o...
....o.+.
........
....o...
.oooo...
o.......
oooo....

( multiple wires )
......
....o.
.p..+.
......
.+..+.
....o.
......

( push two wires at the same time to get them unstuck )
........
...ooo..
..p..o..
.....o..
..o+....
..o+....
..o..o..
..oooo..
........

( can't push 3 )
........
...p....
.o......
.o.+....
.oo+....
...+..o.
......o.
...oooo.
........

( can't push 3, but cute )
........
...p....
........
.o.+++..
...+.+..
...+++..
........
......o.
........

( can't push 3, but tedious and annoying )
o.......
....+++.
...+++..
..+++...
.+++..p.
........
.......o

( trying to make a cool pattern out of the wires )
p.........
.o.+.o.+..
..+.+.+.o.
.+.+.+.+..
..+.+.+.+.
.o.+.+.+..
..+.o.+.o.
..........

( gotta pull 12 out of that ball somehow)
..............
.p...+++++....
.....+.+.+....
.....+++++....
.....+.+.+....
.....+++++....
..............
o............o

message ok bye