vim-fugitive + vim-swoop

fugitive-swoop.vim

function! Cmd2QuickFix(command, prompt, use_swoop)
    " use the current word as the default value
    let default = expand("<cword>")
    call inputsave()
        let pattern = input(a:prompt, default)
    call inputrestore()
    if empty(pattern)
        echo a:command . ' needs a pattern, see :h ' . a:command
    else
        exe 'silent ' . a:command . ' ' . pattern . ' | redraw!'
        let qflist = getqflist()
        let rows = len(qflist)
        if a:use_swoop && rows < 15
            " open all files on the quickfix list
            let s:prev_val = ""
            for d in getqflist()
                let s:curr_val = bufname(d.bufnr)
                if (s:curr_val != s:prev_val)
                    exec "edit " . s:curr_val
                endif
                let s:prev_val = s:curr_val
            endfor
            " start swoop with the original pattern
            call SwoopMultiPattern(pattern)
        else
            " fallback into opening the quickfix window
            cwindow
        endif
    endif
endfunction
command! CustomGgrep call Cmd2QuickFix("Ggrep", "git grep ", 1)
command! CustomGlog call Cmd2QuickFix("Glog -S", "git log -S ", 0)
" git grep the current word
nnoremap <leader>gg :CustomGgrep<CR>
" git log the current word
nnoremap <leader>gl :CustomGlog<CR>