Some script I did to backup my USB drive from time to time

DATA_USBTool.bat

@ECHO OFF
REM Version 1.3.6

TITLE Welcome to DATA_Tools.

IF /I "%CD:~0,2%"=="%SYSTEMDRIVE%" (
ECHO This script must be on the USB drive!
ECHO Canceled operation.
ECHO.
PAUSE
EXIT
)

IF NOT EXIST "%CD%DATA" (
ECHO DATA folder is missing on %CD%!
ECHO Create the folder %CD%DATA, this reexecute this script script.
ECHO Canceled operation.
ECHO.
PAUSE
EXIT
)

:START
SET /P _CHOICE=[S]ave %CD% ou [R]estore %CD%? 
IF /I "%_CHOICE%"=="S" GOTO _S
IF /I "%_CHOICE%"=="R" GOTO _R
ECHO Invalid parameter.
GOTO START

REM Save
:_S
IF EXIST "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup" (
TITLE Deleting last save...
RD /S /Q "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup\"
MKDIR "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup\"
) ELSE (
MKDIR "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup\"
)
TITLE Saving %CD%...
XCOPY "%CD%DATA" "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup" /E /Y /V /C /R
GOTO END

REM Restore
:_R
IF EXIST "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup" (
TITLE Restoring %CD%...
XCOPY "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup" "%CD%DATA" /E /Y /V /C /Z /R
) ELSE (
ECHO Le dossier %SYSTEMDRIVE%\Users\%USERNAME%\Desktop\USB Backup n'existe pas!
)

:END
TITLE Finished!
ECHO Operation has finished.
PAUSE
EXIT