aoc2021-day6

aoc2021-day6.lisp

;;;; +----------------------------------------------------------------+
;;;; | Advent of Code 2021                                            |
;;;; +----------------------------------------------------------------+

(defpackage #:snippets/aoc2021/day6
  (:use #:cl)
  (:export
   #:day6))

(in-package #:snippets/aoc2021/day6)

(defconstant creator-tick 6)
(defconstant initial-tick (+ creator-tick 2))
(defconstant num-ticks (1+ initial-tick))

(defstruct sim
  (counts (make-array num-ticks :initial-element 0))
  (total 0))

(defun create-sim (input)
  (let ((sim (make-sim)))
    (dolist (tick input)
      (incf (aref (sim-counts sim) tick))
      (incf (sim-total sim)))
    sim))

(defun sim-step (sim)
  (let ((creators (aref (sim-counts sim) 0)))
    (replace (sim-counts sim) (sim-counts sim) :start2 1)
    (setf (aref (sim-counts sim) initial-tick) creators)
    (incf (aref (sim-counts sim) creator-tick) creators)
    (incf (sim-total sim) creators)))

(defun sim-walk (sim n)
  (loop repeat n do (sim-step sim))
  (sim-total sim))

(defun day6 (input)
  (let ((sim (create-sim input)))
    (list (sim-walk sim 80)
          (sim-walk sim (- 256 80)))))