Prefix cmd prompt with poetry project name

AutoRun.cmd

:: Computer\HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRun="%USERPROFILE%\AutoRun.cmd"
:: (replace USERPROFILE with actual value)

@echo off
:: skip if already done
if "%RC_CMD%"=="1" goto :skip
cls
prompt $p$g 

:: Update PATH
::set PATH=...;%PATH%
:: Misc extra stuff
::set _NT_SYMBOL_PATH=srv*C:\symbols*http://msdl.microsoft.com/downloads/symbols
:: Custom stuff if admin
net session 1>nul 2>nul && (
  prompt $p# 
  color 47
  cd /D %HOMEPATH%
)
set RC_CMD=1
:skip

if not "%POETRY_ACTIVE%"=="1" goto :skip_poetry
setlocal
set poetry_root=
call :find_poetry_root %cd%
goto :found_poetry_root
:find_poetry_root
if exist "%~f1\pyproject.toml" (
  set poetry_root=%~f1
  goto :eof
)
if "%~p1"=="\" goto :eof
call :find_poetry_root %~f1\..
goto :eof
:found_poetry_root
if "%poetry_root%"=="" goto :skip_poetry
findstr /C:"name\ =" "%poetry_root%\pyproject.toml">"%poetry_root%\.name"
set /p poetry_name=<"%poetry_root%\.name"
del "%poetry_root%\.name"
set poetry_name=%poetry_name:~8,-1%
endlocal && prompt %poetry_name% $p $$ 
:skip_poetry

echo on

Use raw code above for ESC character.