3CXPhone with protocols callto and tel - Windows 10

add-3CXPhone6-tel-to-registry-windows10.bat

@ECHO OFF

REM Set vars
SET projdir=%ProgramFiles%\3CXPhone
SET batfile=%projdir%\3CXPhone.BAT
SET regfile=%projdir%\3CXPhone.REG
IF NOT EXIST "%projdir%" ( MKDIR "%projdir%" )

REM Make .BAT file
(
	ECHO SET executable="C:\Program Files (x86)\3CXPhone\3CXPhone.exe"
	ECHO SET phone=%%1
	ECHO SET phone=%%phone:tel:+=%%
	ECHO SET phone=%%phone:tel:/+=%%
	ECHO SET phone=%%phone:tel://+=%%
	ECHO SET phone=%%phone:tel:=%%
	ECHO SET phone=%%phone:tel:/=%%
	ECHO SET phone=%%phone:tel://=%%
	ECHO SET phone=%%phone:callto:+=%%
	ECHO SET phone=%%phone:callto://+=%%
	ECHO SET phone=%%phone:callto:/+=%%
	ECHO SET phone=%%phone:callto:=%%
	ECHO SET phone=%%phone:callto://=%%
	ECHO SET phone=%%phone:callto:/=%%
	ECHO %%executable%% dial:%%phone%%
) > "%batfile%"

REM Make .REG file
(
	ECHO Windows Registry Editor Version 5.00
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Classes\callto]
	ECHO @="URL:callto"
	ECHO "URL Protocol"=""
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Classes\tel]
	ECHO @="URL:tel"
	ECHO "URL Protocol"=""
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Classes\dialer.callto]
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Classes\dialer.callto\Shell]
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Classes\dialer.callto\Shell\Open]
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Classes\dialer.callto\Shell\Open\Command]
	ECHO @="\"%batfile:\=\\%\" \"%%1\""
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Dialer]
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Dialer\Capabilities]
	ECHO "ApplicationDescription"="Dialer"
	ECHO "ApplicationName"="Dialer"
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\Dialer\Capabilities\URLAssociations]
	ECHO "callto"="dialer.callto"
	ECHO "tel"="dialer.callto"
	ECHO.
	ECHO [HKEY_CURRENT_USER\SOFTWARE\RegisteredApplications]
	ECHO "Dialer"="Software\\Dialer\\Capabilities"
) > "%regfile%"

REM Import .REG file to Windows Registry
REGEDIT.EXE /S "%regfile%"

add-3CXPhone6-tel-to-registry-windows7.bat

@ECHO OFF

REM Set vars
SET projdir=%ProgramFiles%\DataRaptorDialer
SET batfile=%projdir%\DataRaptorDialer.BAT
SET regfile=%projdir%\DataRaptorDialer.REG
IF NOT EXIST "%projdir%" ( MKDIR "%projdir%" )

REM Make .BAT file
(
	ECHO SET executable="C:\Program Files (x86)\3CXPhone\3CXPhone.exe"
	ECHO SET phone=%%1
	ECHO SET phone=%%phone:tel:+=%%
	ECHO SET phone=%%phone:tel://+=%%
	ECHO %%executable%% dial:%%phone%%
) > "%batfile%"

REM Make .REG file
(
	ECHO Windows Registry Editor Version 5.00
	ECHO.
	ECHO [HKEY_CLASSES_ROOT\tel]
	ECHO @="3CXPhone - URL:tel"
	ECHO "URL Protocol"=""
	ECHO.
	ECHO [HKEY_CLASSES_ROOT\tel\DefaultIcon]
	ECHO.
	ECHO [HKEY_CLASSES_ROOT\tel\shell]
	ECHO.
	ECHO [HKEY_CLASSES_ROOT\tel\shell\open]
	ECHO.
	ECHO [HKEY_CLASSES_ROOT\tel\shell\open\command]
	ECHO @="\"%batfile:\=\\%\" \"%%1\""
) > "%regfile%"

REM Import .REG file to Windows Registry
REGEDIT.EXE /S "%regfile%"