ds.define() registers a module under a name. The module's function is called on demand by require().

define.coffee

ds.define = do ->

    modules = {
        ds
        $
        _: _.noConflict()
        Backbone
        Breakpoints
        Raven: window.Raven
        key: key.noConflict()
    }
    initializedModules = modules._.clone modules

    stack = []

    make = (name, required)->
        _ = modules._
        if typeof name is 'string'
            if _.include stack, name
                # This would otherwise go into an infinite loop and throw a
                # "Maximum call stack exceeded error"
                throw new Error "require error: Circular import detected in module #{ name }: #{ stack.join ' > ' } > #{ name }"
            else
                stack.push name
                module = initializedModules[name] or= modules[name]?(require)
                required[name] = module if required
                stack.splice stack.length - 1, 1
                module
        else
            throw new Error "require error: #{ _.toString name } is not a String"

    require = (names...)->
        if names.length is 1
            required = make names[0]
        else
            required = {}
            make(name, required) for name in names
        required

    ds.require = ->
        require.apply null, arguments

    define = (name, module) ->
        modules[name] = ->
            module.call window, require


    define