Funky mixin method.

ImColour.hx

package imgui;

#if macro
    import haxe.macro.Context;
    class ImColourBuild {
        public static function run() {
            var fields = Context.getBuildFields();
            fields.push({
                pos: Context.currentPos(),
                name: "_colour",
                meta: null,
                doc: null,
                access: [APublic],
                kind: FVar(macro :Vec4, null)
            });
            return fields;
        }
    }
#else
    import ogl.GLM;
    class ImColourBuild {}
    class ImColourMixin {
        public static function colour<T>(x:ImColour<T>, colour:Vec4) {
            x._colour = colour;
            return x;
        }
    }
    @:build(imgui.ImColourBuild.run())
    @:autoBuild(imgui.ImColourBuild.run())
    interface ImColour<T> {}
#end

Main.hx

import ogl.GLM;
import imgui.ImColour;
using imgui.ImColour.ImColourMixin;

class Panel implements ImColour<Panel> {
   public function new() {}
}

class Main {
   static function main() {
      new Panel().colour([1,1,1,1]);
   }
}