Tool to launch X11 clients with unique IDs

PKGBUILD

# Maintainer: Denis Oster <[email protected]>

pkgname=wm-launch
pkgver=0.5.1
pkgrel=1
pkgdesc="Tool to launch X11 clients with unique IDs"
arch=("x86_64")
url="https://github.com/jcrd/wm-launch"
license=("GPL" 'custom:GPL3 or any later version')
depends=(libx11)
makedepends=(
  go
  perl
)
source=(
  "${pkgname}-${pkgver}.tar.gz::https://github.com/jcrd/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz"
  "https://gist.githubusercontent.com/denisoster/cc889e61596d7eb712e350b1fe437ad4/raw/769bc6acc52a54b978f005d9a4bccf0b20d1cf18/pod2man.patch")
sha256sums=(
  aedd313507ee44ea9b98094e3435b6677cd316b7e847d42e80089d31a6f00492
  bbd22ae11c45efd75ea43f032e76736afdf947557010fbf5671579bb6a4dafc6
)
_srcdir="${pkgname}-${pkgver}"

prepare() {
  patch --directory="${_srcdir}" --forward --strip=1 --input="$srcdir/pod2man.patch"
}

build() {
  make -C "${_srcdir}" -O V=1 VERBOSE=1 PREFIX=/usr
}

package() {
  make install -C "${_srcdir}" -O V=1 VERBOSE=1 DESTDIR="${pkgdir}" PREFIX=/usr

  install -Dm644 "${_srcdir}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

pod2man.patch

Index: Makefile
IDEA additional info:
Subsystem: com.intellij.openapi.diff.impl.patch.CharsetEP
<+>UTF-8
===================================================================
diff --git a/Makefile b/Makefile
--- a/Makefile	(revision a72500c975a1ab6af7cc94c090fc1244ee27a9d6)
+++ b/Makefile	(date 1660459678425)
@@ -35,7 +35,7 @@
 	go build $<
 
 $(MANPAGE): man/$(MANPAGE).pod
-	pod2man -n=wm-launch -c=wm-launch -r=$(VERSION) $< $(MANPAGE)
+	/usr/bin/core_perl/pod2man -n=wm-launch -c=wm-launch -r=$(VERSION) $< $(MANPAGE)
 
 install:
 	mkdir -p $(DESTDIR)$(BINPREFIX)