PKGBUILD for libfprint with Validity 0090 patches, @3v1n0's repo

PKGBUILD

# Maintainer: Davide Depau <[email protected]>
# Contributor: Ivan Shapovalov <[email protected]>
# Contributor: Sven Greiner <[email protected]>
# Contributor: vldmr <[email protected]>
# Contributor: Thomas Krug <[email protected]>
# Contributor: Matthew Bauer <[email protected]>

pkgname=libfprint-vfs0090-git
epoch=1
pkgver=0.7.0.r87.g877aba1
pkgrel=1
pkgdesc="Library for fingerprint readers (includes WIP libre vfs0090 driver)"
arch=(i686 x86_64)
url="https://github.com/nmikhailov/Validity90"
license=(LGPL)
depends=(libusb nss pixman gnutls openssl)
makedepends=(git)
optdepends=("fprintd: D-Bus daemon that manages fingerprint readers")
groups=(fprint-git)
provides=(libfprint)
conflicts=(libfprint)
source=("git+https://github.com/3v1n0/libfprint.git")
md5sums=('SKIP')

pkgver() {
  cd libfprint
  git describe --long --tags 2>/dev/null | sed 's/^V_//;s/\([0-9]*-g\)/r\1/;s/[-_]/./g'
}

prepare() {
  cd libfprint
  git checkout vfs0090
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd libfprint

  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --disable-static
  make
}

package() {
  cd libfprint

  make DESTDIR="$pkgdir" install
}