BaseCtrl.coffee

class @BaseCtrl

  @register: (app, name) ->
    name ?= @name || @toString().match(/function\s*(.*?)\(/)?[1]
    app.controller name, this

  @inject: (annotations...) ->
    ANNOTATION_REG = /^(\S+)(\s+as\s+(\w+))?$/

    @annotations = _.map annotations, (annotation) ->
      match = annotation.match(ANNOTATION_REG)
      name: match[1], identifier: match[3] or match[1]

    @$inject = _.map @annotations, (annotation) -> annotation.name

  constructor: (dependencies...) ->
    for annotation, index in @constructor.annotations
      this[annotation.identifier] = dependencies[index]

    @initialize?()

FormCtrl.coffee

app = angular.module("myApp")

class FormCtrl extends BaseCtrl

  @register app, "products.FormCtrl"
  @inject "$scope", "$location", "alerts", "product as remote"

  initialize: ->
    @reset()

  save: (product) ->
    promise = product.$save()
    successMessage = if product.persisted() then "Product was updated" else "Product was created"

    promise.then =>
      @alerts.success successMessage
      @$location.path "/products"

  reset: ->
    @product = angular.copy(@remote)
    @$scope.product = @product

  delete: ->
    promise = @product.$delete()
    promise.then =>
      @alerts.info "Product was deleted"
      @$location.path "/products"