[bat] Create backup copy with datetime

Create backup of XXX.bat

@ECHO OFF
REM support "Umlaute äöü" (Use codepage CP-1252 aka "Windows-1252" aka "Latin 1")
CHCP 1252 >nul

TITLE Create backup of XXX

SET "$PS_EXE=powershell.exe"

SET "_SOURCE_FILENAME=xxx.xlsx"
SET "_TARGET_BACKUP_FOLDER=X:\abc\def\geh\backup"

REM Get date YYYY-MM-dd -> (string) _date
SET "_TEMP_FILENAME=___delme.tmp"
%$PS_EXE% -Command "& {Get-Date -Format "yyyy-MM-dd"}">"%_TEMP_FILENAME%"
SET /P "_date="<"%_TEMP_FILENAME%"
DEL "%_TEMP_FILENAME%"

REM Create backup filename using date
SET "_TARGET_BACKUP_FILENAME=xxx_%_date%.xlsx"

REM Backup original
SET "_TARGET_BACKUP_FILE=%_TARGET_BACKUP_FOLDER%\%_TARGET_BACKUP_FILENAME%"
ECHO Backup original file ...
ECHO.  - original: "%_SOURCE_FILENAME%"
ECHO.  - backup:   "%_TARGET_BACKUP_FILENAME%"
ECHO.
XCOPY "%_SOURCE_FILENAME%" "%_TARGET_BACKUP_FILE%*" /-Y
ECHO Done.
ECHO.

REM Show Message
SET "_MSGBOX_TEMP_FILE=_delme_taskfile_msgbox.vbs"
> "%_MSGBOX_TEMP_FILE%" ECHO WScript.Echo ^( "Backup abgeschlossen." ^& vbCrLf ^& "(%_TARGET_BACKUP_FILENAME%)" ^)
WSCRIPT.EXE "%_MSGBOX_TEMP_FILE%"
DEL "%_MSGBOX_TEMP_FILE%"

TITLE Create backup of XXX - DONE