fix-ekho-build-PKGBUILD

# Maintainer: Denis Kasak <dkasak|AT|termina.org.uk>

pkgname=ekho
pkgver=7.7.1
pkgrel=1
pkgdesc="Chinese text-to-speech (TTS) software for Cantonese, Mandarin, Zhaoan Hakka, Tibetan, Ngangien and Korean"
arch=('i686' 'x86_64')
url="http://www.eguidedog.net/ekho.php"
license=('GPL')
makedepends=('automake' 'autoconf')
depends=('libpulse' 'lame' 'festival' 'ncurses' 'espeak')
source=("http://downloads.sourceforge.net/e-guidedog/ekho-${pkgver}.tar.xz"
        "configure.ac.diff")
md5sums=('dadf0739fe6a67e5a1de03750b23a4a7'
         'b16853a626c40a139a359736cf9fb36d')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # fix directory permissions
  find "ekho-data" -type d -exec chmod o+r {} +

  CXXFLAGS="${CXXFLAGS} -fopenmp"
  if [ "${CARCH}" == "x86_64" ]; then
    CXXFLAGS="${CXXFLAGS} -D_x86_64"
  fi

  patch -p0 <"${srcdir}/configure.ac.diff"
  aclocal
  autoconf
  automake

  ./configure --prefix=/usr --with-mp3lame --enable-festival
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}/" install
}