PKGBUILD for wingo-git

wingo.PKGBUILD

# Contributor: Andrew Gallant <[email protected]>
# Contributor: Daniel YC Lin <dlin.tw at gmail>
# Maintainer: Andrew Gallant
pkgname=wingo-git
pkgver=r421.8e0f2c8
pkgrel=1
pkgdesc="An X window manager featuring per-monitor workspaces with floating and tiling placement policies."
arch=(x86_64 i686)
url="https://github.com/BurntSushi/wingo"
license=('WTFPL')
groups=()
makedepends=('go' 'git' 'mercurial')
source=(repo::git+https://github.com/BurntSushi/wingo)
noextract=()
install=wingo.install
md5sums=(SKIP)
pkgver() {
  cd "$srcdir/repo"
  #git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
  mkdir -p $srcdir/src/github.com/BurntSushi
  ln -s "$srcdir/repo"  "$srcdir/src/github.com/BurntSushi/wingo"
}
build() {
  cd "$srcdir"

  msg "go getting wingo... (this may take a while)"
  GOPATH="$srcdir" go get -u -v -x github.com/BurntSushi/wingo

  msg "go getting wingo-cmd..."
  GOPATH="$srcdir" go get -u -v -x github.com/BurntSushi/wingo/wingo-cmd
}
package() {
  cd $srcdir
  # Install the wingo executables.
  install -Dm755 bin/wingo "$pkgdir/usr/bin/wingo"
  install -Dm755 bin/wingo-cmd "$pkgdir/usr/bin/wingo-cmd"

  # Install Wingo documentation.
  cd "$srcdir/src/github.com/BurntSushi/wingo"
  install -Dm644 COMPLIANCE "$pkgdir/usr/share/doc/wingo/COMPLIANCE"
  install -Dm644 COPYING "$pkgdir/usr/share/doc/wingo/COPYING"
  install -Dm644 HOWTO-COMMANDS "$pkgdir/usr/share/doc/wingo/HOWTO-COMMANDS"
  install -Dm644 HOWTO-CONFIGURE "$pkgdir/usr/share/doc/wingo/HOWTO-CONFIGURE"
  install -Dm644 INSTALL "$pkgdir/usr/share/doc/wingo/INSTALL"
  install -Dm644 README.md "$pkgdir/usr/share/doc/wingo/README.md"
  install -Dm644 STYLE "$pkgdir/usr/share/doc/wingo/STYLE"

  # Install Wingo configuration to /etc/xdg/wingo
  cd "$srcdir/src/github.com/BurntSushi/wingo/config"
  install -Dm644 hooks.wini "$pkgdir/etc/xdg/wingo/hooks.wini"
  install -Dm644 key.wini "$pkgdir/etc/xdg/wingo/key.wini"
  install -Dm644 mouse.wini "$pkgdir/etc/xdg/wingo/mouse.wini"
  install -Dm644 options.wini "$pkgdir/etc/xdg/wingo/options.wini"
  install -Dm644 theme.wini "$pkgdir/etc/xdg/wingo/theme.wini"

  # Install Wingo data files to /usr/share/wingo
  cd "$srcdir/src/github.com/BurntSushi/wingo/data"
  install -Dm644 DejaVuSans.ttf "$pkgdir/usr/share/wingo/DejaVuSans.ttf"
  install -Dm644 wingo.wav "$pkgdir/usr/share/wingo/wingo.wav"
  install -Dm644 wingo.png "$pkgdir/usr/share/wingo/wingo.png"
  install -Dm644 close.png "$pkgdir/usr/share/wingo/close.png"
  install -Dm644 minimize.png "$pkgdir/usr/share/wingo/minimize.png"
  install -Dm644 maximize.png "$pkgdir/usr/share/wingo/maximize.png"

  # Install Wingo xsession file to /usr/share/xsessions
  cd "$srcdir/src/github.com/BurntSushi/wingo/data/archlinux/wingo-git"
  install -Dm644 wingo.desktop "$pkgdir/usr/share/xsessions/wingo.desktop"
}