Use ibuffer to access (hidden) WL messages

gistfile1.el

(defun wl-message-ibuffer-predicate ()
  (and (boundp 'wl-message-buffer-cur-folder)
       (boundp 'wl-message-buffer-cur-number)
       wl-message-buffer-cur-folder
       wl-message-buffer-cur-number))

(define-ibuffer-column wl-message-date (:name "Date")
  (format-time-string "%Y-%m-%d"
                      (elmo-message-field (wl-folder-get-elmo-folder wl-message-buffer-cur-folder) wl-message-buffer-cur-number 'date)))

(define-ibuffer-column wl-message-subject (:name "Subject")
  (elmo-message-field (wl-folder-get-elmo-folder wl-message-buffer-cur-folder) wl-message-buffer-cur-number 'subject))

(define-ibuffer-column wl-message-from (:name "From")
  (elmo-message-field (wl-folder-get-elmo-folder wl-message-buffer-cur-folder) wl-message-buffer-cur-number 'from))

(defvar wl-message-ibuffer-formats
  '(((wl-message-date 20 20) " " (wl-message-from 40 40) " " (wl-message-subject 0 -1 :left :elide))))

(defun wl-message-ibuffer ()
  (interactive)
  (let ((ibuffer-maybe-show-predicates nil))
    (ibuffer t "*WL Messages*" '((predicate . (wl-message-ibuffer-predicate))) nil nil nil wl-message-ibuffer-formats)))