Example of driving an Adafruit NeoPixel Ring with the Digispark Arduino-compatible board

NeoPixelTest.ino

#include <Adafruit_NeoPixel.h>

#define PIN 1
#define STRIPSIZE 16

// Parameter 1 = number of pixels in strip
// Parameter 2 = pin number (most are valid)
// Parameter 3 = pixel type flags, add together as needed:
//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
//   NEO_GRB     Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB     Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(STRIPSIZE, PIN, NEO_GRB + NEO_KHZ800);

void setup() {
  strip.begin();
  strip.setBrightness(25);  // Lower brightness and save eyeballs!
  strip.show(); // Initialize all pixels to 'off'
}

void loop() {
  // Some example procedures showing how to display to the pixels:
  colorWipe(strip.Color(0,0,0), 25); // Black
  colorWipe(strip.Color(64, 0, 0), 100); // Red
  colorWipe(strip.Color(0, 64, 0), 100); // Green
  colorWipe(strip.Color(0, 0, 64), 100); // Blue
  colorWave(75);
  colorWipe(strip.Color(0,0,0), 100); // Black
  rainbow(15);
  colorWipe(strip.Color(0,0,0), 100); // Black
  rainbowCycle(15);
  colorWipe(strip.Color(0,0,0), 100); // Black
  colorWave(30);
}

// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
  for(uint16_t i=0; i<strip.numPixels(); i++) {
      strip.setPixelColor(i, c);
      strip.show();
      delay(wait);
  }
}

void rainbow(uint8_t wait) {
  uint16_t i, j;

  for(j=0; j<256; j++) {
    for(i=0; i<strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel((i+j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
  uint16_t i, j;

  for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel
    for(i=0; i< strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
  if(WheelPos < 85) {
   return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
  } else if(WheelPos < 170) {
   WheelPos -= 85;
   return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  } else {
   WheelPos -= 170;
   return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
}

/**
 *      ^   ^   ^  
 * ~~~~~ ColorWave ~~~~~
 *        V   V   V   
 */
void colorWave(uint8_t wait) {
  int i, j, stripsize, cycle;
  float ang, rsin, gsin, bsin, offset;

  static int tick = 0;
  
  stripsize = strip.numPixels();
  cycle = stripsize * 25; // times around the circle...

  while (++tick % cycle) {
    offset = map2PI(tick);

    for (i = 0; i < stripsize; i++) {
      ang = map2PI(i) - offset;
      rsin = sin(ang);
      gsin = sin(2.0 * ang / 3.0 + map2PI(int(stripsize/6)));
      bsin = sin(4.0 * ang / 5.0 + map2PI(int(stripsize/3)));
      strip.setPixelColor(i, strip.Color(trigScale(rsin), trigScale(gsin), trigScale(bsin)));
    }

    strip.show();
    delay(wait);
  }

}

/**
 * Scale a value returned from a trig function to a byte value.
 * [-1, +1] -> [0, 254] 
 * Note that we ignore the possible value of 255, for efficiency,
 * and because nobody will be able to differentiate between the
 * brightness levels of 254 and 255.
 */
byte trigScale(float val) {
  val += 1.0; // move range to [0.0, 2.0]
  val *= 127.0; // move range to [0.0, 254.0]

  return int(val) & 255;
}

/**
 * Map an integer so that [0, striplength] -> [0, 2PI]
 */
float map2PI(int i) {
  return PI*2.0*float(i) / float(strip.numPixels());
}

#Hi

I really love you're project . I'm trying to combine a couple of codes , but i do not understand it .
How can I make you're project work with a button ? The thing I want to do is , if my daughter pushes a button , a new cycle begins . Until that button is pushed again I want that cycle to loop .

I would like to have her choose out of sollid colors , and the rainbow effect .

The text under this one is a copy paste of my help I asked on the arduino forum

---

I really hope you can help me out with this.
If it would be possible , I want to add you're code and the other code in one file .

I'm a real noob in arduino language , to bad I don't speak it :)

I am doing a project for my daughter . I have a old boring ceiling light and I integrated a neopixel ring with 24 leds.
I was very lucky that the excisting led ring was the same inner diameter as the neo pixel ring so I could attach the ring to this piece to keep it in place

I found the code here https://www.hackster.io/Arnov_Sharma_makes/neopixel-x-arduino-x-button-c26e9a

But I am struggling a bit with the code . I want to adjust it , but as I 've mentioned before I'm a noob at programming .

Here is my problem

I have 5 solid colors in a row . Those work fine each time I push the button to change the color.

The 6 th an 7 th push of the button gives me the rainbow ,rainbowcycle and theaterChaseRainbow ( case 6 and 7 and 8 in the sketch ) but I want those be in a loop .

when I come to case 6 , I can't go to case 7 until the complete cycle has ended . The same if I want to go from case 7 to 8 I have to wait until the cyclus is ended .

so this is what I want :
I just want to get every rainbow effect in a loop and toggle all modes with the touch of a button without waiting ,so my daughter can choose what mood effect she wants . , and get everything rainbow effect in a loop .

I really hope someone can help me out , because it's kind of a x mass gift and I've been struggling all week long .

Stay save and happy holidays

Greetings from Belgium Bart

this is a short video of my project

https://drive.google.com/file/d/18LpYH4Bhq7iLBnTJF2-q1Yysc98BOOdo/view?usp=sharing